DokHak Solidity - Token Vault

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IERC20 {
    function totalSupply() external view returns (uint256);
    function balanceOf(address account) external view returns (uint256);
    function transfer(address recipient, uint256 amount) external returns (bool);
    function allowance(address owner, address spender) external view returns (uint256);
    function approve(address spender, uint256 amount) external returns (bool);
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.10;
import "../src/IERC20.sol";

// MockERC20은 테스트를 위해 실제 ERC20 토큰의 동작을 흉내 내는 가짜 토큰 컨트랙트
contract MockERC20 is IERC20 {
    // 토큰의 기본 메타데이터 정보
    string public name = "Mock Token";
    string public symbol = "MTK";
    uint8 public decimals = 18;

    // 전체 발행량과 사용자별 잔액, 권한(Allowance)을 관리하는 상태 변수
    uint256 public override totalSupply;
    mapping(address => uint256) public override balanceOf;
    // allowance[주인][대리인] = 금액 : 주인이 대리인에게 인출을 허용한 금액
    mapping(address => mapping(address => uint256)) public override allowance;

    constructor() {}

    // [테스트 전용 함수] 테스트 엔진이 토큰을 무한정 생성해서 테스트 유저에게 나눠줄 때 사용
    // 실제 운영되는 토큰에서는 매우 위험하므로 onlyOwner와 같은 제한이 걸리거나 생성자에서만 실행
    function mint(address to, uint256 amount) public {
        totalSupply += amount; // 전체 발행량 증가
        balanceOf[to] += amount; // 수령인 잔액 증가
        emit Transfer(address(0), to, amount); // 발행(Mint) 이벤트: address(0)은 무에서 유가 창조됨을 의미
    }

    // [IERC20 규격] msg.sender(나)가 spender(금고 등)에게 내 토큰을 일정량 가져갈 수 있도록 허락
    // DeFi 서비스와 상호작용할 때 가장 먼저 호출해야 하는 필수 함수
    function approve(address spender, uint256 amount) public override returns (bool) {
        allowance[msg.sender][spender] = amount; // 대리인에게 권한 부여
        emit Approval(msg.sender, spender, amount); // 권한 부여 로그 발행
        return true;
    }

    // [IERC20 규격] 내가 누군가에게 직접 토큰을 보낼 때 사용
    function transfer(address recipient, uint256 amount) public override returns (bool) {
        balanceOf[msg.sender] -= amount; // 보낸 사람 잔액 차감
        balanceOf[recipient] += amount; // 받는 사람 잔액 증가
        emit Transfer(msg.sender, recipient, amount); // 전송 로그 발행
        return true;
    }

    // [IERC20 규격] 금고(Vault)가 사용자를 대신해 토큰을 가져갈 때 사용
    // 이 함수가 성공하려면, 미리 'sender'가 'msg.sender(금고)'에게 approve를 해두어야 함
    function transferFrom(address sender, address recipient, uint256 amount) public override returns (bool) {
        // 1. 금고가 사용자의 토큰을 가져갈 권한이 있는지 확인하고 권한 금액을 차감
        // solidity 0.8 이상에서는 권한이 부족하면 아래 줄에서 자동으로 Underflow 에러로 Revert 
        allowance[sender][msg.sender] -= amount; 

        // 2. 실제 토큰 주인의 잔액을 차감하고 수령인(보통 금고 자신)에게 전달
        balanceOf[sender] -= amount;  // 나
        balanceOf[recipient] += amount; // 금고

        // 3. 전송 로그 발행
        emit Transfer(sender, recipient, amount);
        return true;
    }
}

(1) 예치 시 0.1% 수수료가 정확히 차감되고 잔액이 기록되는지 확인하는 `test_Deposit_AddsBalanceAfterFee()` 테스트
↓  
(2) 테스트 유저 생성(`makeAddr("user")`) 
↓  
(3) 🎯 `MockERC20`으로 `mint(user, 100)` → `approve(vault, 100)` 수행 
// approve: 실제 토큰 주인(user)이 금고(vault)에게 권한을 주는 행위
// 권한을 주면, 금고가 주인의 토큰을 예치할 수 있음
↓  
(4) 금고에서 `deposit`
// approve 수행하지 않았으면 Revert 발생
↓  
(5) 검증 (사용자 잔액, 금고 누적 수수료 확인)

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.10;
import "./IERC20.sol";

contract TokenVault {
    error NotOwner();
    error ZeroAmount();
    error InsufficientBalance();

    event Deposited(address indexed from, uint256 amount);
    event Withdrawn(address indexed to, uint256 amount);
    event FeesWithdrawn(address indexed to, uint256 amount);

    // 외부에서 항상 일정한 토큰 주소 조회 가능 + 상태 변경 불가능한 최적 조합
    IERC20 public immutable token;
    // 수수료 전용 장부
    // * 계정은 실제 지갑 주소로 불리지만, 여기선 내장 장부상의 논리적인 구분을 의미함
    uint256 internal feeAccumulated;
    address payable private owner;

    mapping(address => uint256) private balances;

    constructor(address _tokenAddress) {
        // IERC20 표준 규격을 사용하는 토큰 강제
        token = IERC20(_tokenAddress);
        owner = payable(msg.sender);
    }

    modifier onlyOwner() {
        if(msg.sender != owner) revert NotOwner();
        _;
    }

	// 예치 
    function deposit(uint256 amount) external {
        if (amount == 0) revert ZeroAmount();
        uint256 fee = amount * 1 / 1000; // 0.1%
        uint256 amountAfterFee = amount - fee;

        // 사용자의 토큰을 금고로 가져온다.
        // 여기서 권한이 없으면 arithmeticError 발생
        token.transferFrom(msg.sender, address(this), amount);

        // 별도 계정에 수수료 누적
        // 나중에 owner가 전체 인출할 누적 수수료
        feeAccumulated += fee;

        // 사용자 토큰 잔액은 금고 계정에 기록
        balances[msg.sender] += amountAfterFee;

        emit Deposited(msg.sender, amountAfterFee);
    }

	// 예치금 인출 
    function withdraw(uint256 amount) external {
        if(balances[msg.sender] < amount) revert InsufficientBalance();

        balances[msg.sender] -= amount;
        token.transfer(msg.sender, amount); // 실제 토큰 전송

        emit Withdrawn(msg.sender, amount);
    }

	// 컨트랙트 소유자의 수수료 인출
    function withdrawFees() external onlyOwner {
        if (feeAccumulated == 0) revert ZeroAmount();
        uint256 amount = feeAccumulated;

        feeAccumulated = 0;
        token.transfer(owner, amount);

        emit FeesWithdrawn(owner, amount);
    }

	// 주소별 잔액 조회 
    // function getBalance(address account) external view returns (uint256) {}

	// 금고 누적 수수료 조회 
    // function getFeeAccumulated() external view returns (uint256) {}
}

uint256 result = 1 / 2; 
// 결과는 0